【マイクラ】teamコマンドの使い方・構文・チーム設定を解説【Java版】

この記事はマイクラJava版の /team コマンド解説です
統合版（BE）にはJava版と同じ仕様の /team コマンドはありません
Java版26.1.2時点で確認した構文をベースに整理しています

こんにちは。ゆずかきです。

マイクラでPvPワールドや配布マップを作っていると、

「赤チームと青チームに分けたい」
「味方同士で攻撃できないようにしたい」
「プレイヤー名の色を変えたい」
「名前表示を隠して、かくれんぼみたいな遊びを作りたい」

…という場面が出てきませんか？

そういう時に使うのが、Java版の /team コマンドです。

team という名前だけ聞くと、ただプレイヤーをグループ分けするだけに見えますが、実際にはかなり便利です。
チームごとに、名前の色・接頭辞・接尾辞・同士討ち・当たり判定・名前表示・死亡メッセージまでまとめて設定できます。

この記事を読めば、次のことが出来るようになります。

Java版でチームを作成・削除できます👌

プレイヤーやモブをチームに参加させられます

名前色・プレイヤー名の前後表示・PvP設定を変更できます

team= セレクターを使って、チーム単位でコマンドを実行できます

コマンド系は最初だけ難しく見えますが、基本の型さえ覚えればかなり使いやすいです。
この記事では、実際に入力する順番で解説していきますね。

※本記事はJava版向けです。統合版では同じ /team コマンドは使えません。
※コマンドを使うには、シングルならチートの許可、サーバーなら権限が必要です。
※Java版は2026年からバージョン表記が 26.x 方式へ変わっています。この記事ではJava版26.1.2時点の仕様をベースにしています。

1. teamコマンドとは
2. 使う前に知っておきたい注意点
3. teamコマンドの基本構文一覧
4. チームを作成してプレイヤーを参加させる
5. チーム一覧・メンバー確認・脱退・削除の使い方
6. team modifyで変更できるチーム設定一覧
7. 名前の色・接頭辞・接尾辞を設定する
8. 同士討ち・透明化・当たり判定の設定
9. 名札表示・死亡メッセージの表示設定
10. teamセレクターと実用コマンド例
11. teammsgでチーム内チャットを送る
12. うまく動かない時のチェックポイント
13. まとめ
14. 参考文献

この記事で分かること
・Java版の /team コマンドの基本構文
・PvP・配布マップ・サーバー運営でよく使う設定例
・初心者が間違えやすい collisionRule や nametagVisibility の意味

1. teamコマンドとは

/team コマンドは、Java版でプレイヤーやエンティティをチーム分けするためのコマンドです。

チームに入れる対象は、プレイヤーだけではありません。
ゾンビ、村人、防具立て、アイテム、矢など、セレクターで指定できるエンティティもチームに参加させられます。

たとえば、こんなことができます。

赤チーム・青チームを作る
味方同士の攻撃を無効化する
チームごとに名前の色を変える
プレイヤー名の前に [赤] のような表示を付ける
チーム内だけ名前表示を見えるようにする
当たり判定を変えて、味方同士で押し合わないようにする
発光エフェクトの輪郭色をチーム色にする

要するに、/team はマルチプレイ用のチーム分け機能でありつつ、配布マップ制作・ミニゲーム制作・検証ワールド作りでもかなり使えるコマンドです。

特に便利なのが、チームに入れた対象をセレクターで指定できることです。

/effect give @a[team=red] minecraft:speed 10 1 true

👆このように書けば、red チームのプレイヤーだけに移動速度上昇を付けられます。

/team を覚えると、ただのコマンド実行ではなく、「赤チームだけ」「チーム未所属だけ」「特定チーム以外だけ」みたいな制御ができるようになります。
ここがかなり便利です。

2. 使う前に知っておきたい注意点

まず大前提として、/team コマンドはJava版限定です。
統合版にも /scoreboard や /tag はありますが、Java版と同じ /team コマンドは使えません。

ここを混同すると、Switchやスマホでコマンドを入力しても、そもそも構文が通らないので注意しましょう。

また、コマンドを使うには権限が必要です。

シングルプレイ：ワールド作成時に「チートの許可」をオンにする
既存ワールド：LANに公開→チートの許可をオンにして一時的に使う
サーバー：OP権限、またはコマンド実行権限が必要
コマンドブロック：サーバー設定でコマンドブロックが有効になっている必要あり

それから、Java版のバージョン表記についても少しだけ注意です。

Java版は長い間 1.21.11 のような表記でしたが、2026年からは年をベースにした 26.x 系の表記へ変わっています。
この記事ではJava版26.1.2時点で確認できる構文を整理しています。

バージョン変更点メモ
/team コマンド自体はJava版1.13で追加され、それ以前の古いバージョンでは /scoreboard teams 系の構文でした。
Java版1.21.11以降、26.1.2時点までで、この記事に載せている基本的な /team 構文に大きな変更は確認していません。
ただし、サーバー運営者はJava版26.1以降の動作環境やサーバー側仕様変更には注意してください。

初心者さん向けに一言でまとめると、

今のJava版なら /team を使う。古い解説にある /scoreboard teams は基本的に昔の構文。

この理解でOKです。

3. teamコマンドの基本構文一覧

/team コマンドの基本形は、下記です。

目的	構文	意味
チーム一覧を見る	`/team list`	作成済みのチーム一覧を表示します
特定チームのメンバーを見る	`/team list <team>`	指定したチームに誰が入っているか確認します
チームを作る	`/team add <team> [displayName]`	新しいチームを作成します
チームを削除する	`/team remove <team>`	チーム自体を削除します
チームを空にする	`/team empty <team>`	チームは残したまま、メンバーだけ全員外します
チームに入れる	`/team join <team> [members]`	プレイヤーやエンティティをチームに参加させます
チームから外す	`/team leave <members>`	指定した対象を現在のチームから脱退させます
設定を変える	`/team modify <team> <option> <value>`	チーム色・同士討ち・当たり判定などを変更します

<team> は、内部的に使うチームIDです。
ここには日本語や空白を使わず、red、blue、staff、spectator のように、英数字中心の短い名前にするのがおすすめです。

/team add red
/team add blue

👆このように、まずはシンプルな英語名で作るのが安全です。

日本語で見せたい名前は、チームIDではなく表示名に入れましょう。

/team add red {"text":"赤チーム"}
/team add blue {"text":"青チーム"}

この場合、内部IDは red と blue。
プレイヤーから見える表示名は「赤チーム」「青チーム」になります。

初心者さん向けメモ
コマンドで使うIDは英数字、画面に見せる名前は日本語OK。
この分け方にしておくと、後からミスが減ります。

4. チームを作成してプレイヤーを参加させる

では実際に、赤チームと青チームを作ってみましょう。
コマンドは上から順番に入力すればOKです。

赤チームと青チームを作る

/team add red {"text":"赤チーム"}
/team add blue {"text":"青チーム"}

これで、red と blue という2つのチームが作成されます。

チーム作成後は、プレイヤーを参加させます。

/team join red Steve
/team join blue Alex

この例では、Steveを赤チーム、Alexを青チームに入れています。

自分自身をチームに入れるだけなら、プレイヤー名を省略できます。

/team join red

ただし、コマンドブロックやサーバーコンソールから実行する場合は対象を省略しない方が安全です。
コマンドブロックはプレイヤーではないので、「誰を入れるの？」という状態になりやすいからです。

コマンドブロックで使うなら、基本はこうです。

/team join red @p

近くのプレイヤーを赤チームに入れる、という意味ですね。

全員をまとめてチームに入れる

全員を赤チームに入れたい場合は、@a を使います。

/team join red @a

@a は全プレイヤーを指定するセレクターです。
PvPの準備中に全員を一度観戦チームに入れる、みたいな場面でも使えます。

モブやエンティティをチームに入れる

/team はプレイヤー専用ではありません。
近くのゾンビ1体を赤チームに入れるなら、こう書けます。

/team join red @e[type=minecraft:zombie,limit=1,sort=nearest]

近くの村人を全員 npc チームに入れるなら、こうです。

/team add npc {"text":"NPC"}
/team join npc @e[type=minecraft:villager,distance=..30]

これを使うと、配布マップでNPC役の村人をまとめて管理したり、発光色を統一したりできます。

ここ大事です
1つのエンティティが同時に入れるチームは1つだけです。
すでに別チームに入っている対象を新しいチームへ参加させると、前のチームからは外れます。

5. チーム一覧・メンバー確認・脱退・削除の使い方

チームを作ったら、まずは確認コマンドも覚えておくと安心です。

作成済みチームを確認する

/team list

現在作成されているチーム一覧が表示されます。
赤チーム・青チームを作った直後なら、ここで red と blue が確認できます。

特定チームのメンバーを確認する

/team list red

red チームに所属しているメンバーを確認できます。
誰がどのチームに入ったか分からなくなった時は、まずこのコマンドを使いましょう。

チームから外す

特定のプレイヤーをチームから外す場合は、leave を使います。

/team leave Steve

全プレイヤーをチームから外したい場合は、こうです。

/team leave @a

モブも対象にできます。

/team leave @e[type=minecraft:villager,distance=..30]

チームは残してメンバーだけ空にする

チーム設定は残したまま、所属メンバーだけ全員外したい場合は empty を使います。

/team empty red

これは、ミニゲームの試合終了時に便利です。
チーム色やPvP設定は残して、次の試合前にメンバーだけ入れ直せます。

チーム自体を削除する

チームそのものを消すなら remove です。

/team remove red

これはチームを完全に削除します。
チーム設定も消えるので、また使う可能性があるなら empty、完全に不要なら remove と覚えると分かりやすいです。

6. team modifyで変更できるチーム設定一覧

/team で一番よく使うのが、modify です。

/team modify <team> <option> <value>

この形で、チームの細かい設定を変更します。
主な設定は下記です。

option	設定できる内容	よく使う場面
`displayName`	チームの表示名	チーム名を日本語で見せたい時
`color`	名前色・TAB表示色・発光輪郭色など	赤チーム、青チームの見分け
`friendlyFire`	味方同士の直接ダメージ可否	PvPで同士討ちを防ぐ
`seeFriendlyInvisibles`	透明化した味方を半透明で見えるか	透明化を使うPvPやマップ制作
`nametagVisibility`	頭上の名前表示	かくれんぼ、ステルス系ミニゲーム
`deathMessageVisibility`	死亡メッセージの表示範囲	PvPログを見せる/隠す
`collisionRule`	押し合い・当たり判定	ロビー、PvP、NPC整理
`prefix`	プレイヤー名の前に付ける文字	`[赤]` Steve のような表示
`suffix`	プレイヤー名の後ろに付ける文字	Steve `[観戦]` のような表示

特に覚えておくと便利なのは、下記の5つです。

color：名前の色を変える
prefix：名前の前に文字を付ける
friendlyFire：同士討ちを切る
collisionRule：押し合いを変える
nametagVisibility：名前表示を隠す

最初から全部覚える必要はありません。
まずは、チーム作成→色変更→メンバー追加→同士討ち無効化まで出来れば、PvPワールドの基本形は作れます。

7. 名前の色・接頭辞・接尾辞を設定する

チーム機能で最初に触るなら、名前の色変更がおすすめです。
見た目に反映されるので、成功したか分かりやすいです。

チームカラーを設定する

赤チームを赤色にするなら、こうです。

/team modify red color red

青チームを青色にするなら、こうです。

/team modify blue color blue

設定できる色は、主に下記です。

色	コマンド値
黒	`black`
濃い青	`dark_blue`
濃い緑	`dark_green`
濃い水色	`dark_aqua`
濃い赤	`dark_red`
濃い紫	`dark_purple`
金色	`gold`
灰色	`gray`
濃い灰色	`dark_gray`
青	`blue`
緑	`green`
水色	`aqua`
赤	`red`
薄紫	`light_purple`
黄色	`yellow`
白	`white`
リセット	`reset`

チームカラーは、プレイヤー名だけでなく、発光エフェクトの輪郭色にも関係します。

/effect give @a[team=red] minecraft:glowing 999999 0 true

赤チームに発光を付けると、輪郭色も赤系になります。
PvPやミニゲームでチームを見分けやすくしたい時に便利です。

接頭辞を付ける

プレイヤー名の前に [赤] のような表示を付けるには、prefix を使います。

/team modify red prefix {"text":"[赤] ","color":"red"}

これで、名前の前に [赤] が付きます。
見た目としては、

[赤] Steve

のような表示になります。

接尾辞を付ける

名前の後ろに表示を付けたい場合は、suffix です。

/team modify red suffix {"text":" ★","color":"yellow"}

この場合、

[赤] Steve ★

のように見せられます。

注意点
prefix と suffix は便利ですが、長くしすぎるとチャット欄やTABリストが見づらくなります。
[赤]、[青]、[観戦] くらいの短い表示にしておくのがおすすめです。

表示名を後から変更する

チームの表示名を後から変えたい場合は、displayName を使います。

/team modify red displayName {"text":"レッドチーム","color":"red"}

チームIDは red のまま、表示名だけ「レッドチーム」に変えられます。

8. 同士討ち・透明化・当たり判定の設定

ここからは、PvPやマルチプレイでかなり重要な設定です。
特に friendlyFire と collisionRule は、ミニゲームを作るならよく使います。

味方同士の攻撃を無効化する

赤チームの同士討ちを無効化するには、こう書きます。

/team modify red friendlyFire false

青チームも同じように設定します。

/team modify blue friendlyFire false

これで、同じチームのプレイヤー同士では直接ダメージを与えられなくなります。
PvPで「味方を間違えて殴る」事故を減らせるので、基本的には入れておくと安心です。

初期値は true なので、何も設定していない場合は味方同士でも攻撃できます。

/team modify red friendlyFire true

👆元に戻したい場合は true です。

注意！
friendlyFire false は、主にチームメンバーのプレイヤー同士の直接ダメージ制御です。
モブの敵対AIを止めるコマンドではありません。
また、状態効果などは別扱いになる場合があるので、完全な無敵化コマンドとしては使わない方が安全です。

透明化した味方を見えるようにする

透明化ポーションなどで透明になった味方を、同じチームから半透明で見えるようにする設定が seeFriendlyInvisibles です。

/team modify red seeFriendlyInvisibles true

初期値は true です。
つまり、同じチームの透明化プレイヤーは、味方から半透明に見えます。

完全に見えないようにしたい場合は、false にします。

/team modify red seeFriendlyInvisibles false

当たり判定を変更する

プレイヤー同士で押し合うかどうかを変えるのが、collisionRule です。

ロビーや待機所で、プレイヤー同士が押し合って邪魔になる場合は、まずこれを使うのが分かりやすいです。

/team modify lobby collisionRule never

never にすると、そのチームのエンティティは他のエンティティと押し合わなくなります。

設定値は下記です。

値	意味	使いどころ
`always`	通常通り当たり判定あり	初期状態に戻す
`never`	誰とも押し合わない	ロビー、待機所、NPC固定
`pushOtherTeams`	同じチーム同士だけ押し合う	特殊なミニゲーム向け
`pushOwnTeam`	別チーム相手だけ押し合う	味方同士の押し合いを避けたいPvP向け

ここ、少し紛らわしいです。
名前だけ見ると pushOtherTeams と pushOwnTeam の意味を逆に覚えやすいので、実際の使い道で覚えるのがおすすめです。

ロビーで誰とも押し合いたくない → never
味方同士だけ押し合わないPvPにしたい → pushOwnTeam
普通に戻したい → always

迷ったら、最初は never か always だけ使えば大丈夫です。

ロビー用チームの例

プレイヤー同士が押し合わないロビー用チームを作るなら、こうです。

/team add lobby {"text":"ロビー"}
/team modify lobby collisionRule never
/team join lobby @a

これで、全員を lobby チームに入れて、押し合いを止められます。
サーバーの待機場所やイベント前の集合場所で便利です。

9. 名札表示・死亡メッセージの表示設定

nametagVisibility は、プレイヤーの頭上に表示される名前を制御する設定です。
かくれんぼ、鬼ごっこ、PvP、アドベンチャーマップでよく使います。

名前表示を完全に隠す

赤チームの名前表示を誰からも見えないようにするなら、こうです。

/team modify red nametagVisibility never

これで、赤チームのプレイヤー名が頭上に表示されなくなります。

元に戻す場合は、always です。

/team modify red nametagVisibility always

同じチームだけ名前を見えるようにする

味方には名前を見せたいけど、敵チームには隠したい場合は、hideForOtherTeams を使います。

/team modify red nametagVisibility hideForOtherTeams

この設定にすると、赤チームの名前は赤チームの味方からだけ見えるようになります。
敵チームからは見えません。

かくれんぼ系やチーム対抗PvPでは、この設定がかなり使いやすいです。

同じチームからだけ名前を隠す

逆に、同じチームからだけ名前を隠したい場合は、hideForOwnTeam です。

/team modify red nametagVisibility hideForOwnTeam

少し特殊な設定なので、最初はあまり使わないかもしれません。
基本は、

全員に見せる → always
誰にも見せない → never
味方にだけ見せる → hideForOtherTeams

この3つを覚えれば十分です。

死亡メッセージを制御する

死亡メッセージの表示範囲は、deathMessageVisibility で変更できます。

/team modify red deathMessageVisibility never

never にすると、赤チームの死亡メッセージが表示されなくなります。

設定値は nametagVisibility と同じく、下記の4つです。

値	死亡メッセージの表示
`always`	全員に表示する
`never`	誰にも表示しない
`hideForOtherTeams`	同じチームにだけ表示する
`hideForOwnTeam`	同じチームには表示しない

PvPで倒されたことを全体に見せたいなら always。
かくれんぼや人狼風の遊びで死亡を隠したいなら never。
チーム内だけに知らせたいなら hideForOtherTeams。

このように、遊び方に合わせて選ぶと良いです。

10. teamセレクターと実用コマンド例

/team は、作って終わりではありません。
本当に便利なのは、セレクターと組み合わせた時です。

Java版では、@a[team=red] のように書くことで、特定チームだけを対象にできます。

チーム指定の基本

書き方	意味
`@a[team=red]`	redチームのプレイヤー
`@a[team=!red]`	redチームではないプレイヤー
`@a[team=]`	どのチームにも入っていないプレイヤー
`@a[team=!]`	何らかのチームに入っているプレイヤー

! は「〜ではない」という意味で使います。
ここを覚えると、かなり応用しやすくなります。

赤チームだけにスピードを付ける

/effect give @a[team=red] minecraft:speed 30 1 true

赤チームのプレイヤーだけに、30秒間の移動速度上昇を付けます。

青チームだけを拠点へテレポートする

/tp @a[team=blue] 100 64 100

青チームだけを指定座標へ移動します。
試合開始前にチームごとの待機場所へ送る時に便利です。

チーム未所属の人だけロビーへ送る

/tp @a[team=] 0 80 0

どのチームにも入っていない人だけをロビーへ移動します。
参加処理漏れの人を集めたい時に使えます。

赤チーム以外に暗視を付ける

/effect give @a[team=!red] minecraft:night_vision 60 0 true

赤チーム以外のプレイヤーに暗視を付けます。
鬼ごっこ系で「鬼以外に補助効果を付ける」みたいな使い方ができます。

チーム別にタイトルを表示する

/title @a[team=red] title {"text":"赤チームの勝利！","color":"red"}
/title @a[team=blue] title {"text":"青チームの勝利！","color":"blue"}

チーム別に違うメッセージを出したい時に便利です。

発光色をチームごとに分ける

/team modify red color red
/team modify blue color blue
/effect give @a[team=red] minecraft:glowing 999999 0 true
/effect give @a[team=blue] minecraft:glowing 999999 0 true

チームカラーを設定したうえで発光を付けると、チームごとの識別がかなりしやすくなります。
配布マップの演出やPvPの観戦用にも使いやすいです。

11. teammsgでチーム内チャットを送る

Java版には、チーム内メッセージ用のコマンドもあります。
それが /teammsg です。

短縮形として /tm も使えます。

/teammsg 右側から攻めます

または、

/tm 右側から攻めます

同じチームのプレイヤーにだけメッセージを送れます。
PvPや協力マップで、味方だけに作戦を伝えたい時に便利ですね。

ただし、/teammsg は実行者がチームに入っている必要があります。
チーム未所属の状態で使うと失敗します。

使いどころ
普段のサバイバルではあまり使わないかもしれませんが、チーム戦のイベントや配布マップでは便利です。
コマンドブロックで無理に使うというより、プレイヤーが手入力するチームチャットとして覚えると分かりやすいです。

12. うまく動かない時のチェックポイント

/team コマンドがうまく動かない時は、だいたい原因が決まっています。
順番に確認してみてください。

[ ] Java版で実行しているか？（統合版では同じ /team は使えません）
[ ] チート、またはOP権限があるか？
[ ] チームIDに空白や日本語を入れていないか？
[ ] red と Red のように大文字小文字を間違えていないか？
[ ] 先に /team add でチームを作っているか？
[ ] コマンドブロックで members を省略していないか？
[ ] JSON部分の " や {} が抜けていないか？
[ ] 対象セレクターが空振りしていないか？
[ ] すでに別チームへ移動していないか？

特に多いのが、チームを作る前に参加させようとしているケースです。

/team join red @p

このコマンドは、red チームが存在していないと失敗します。
先に必ず作成しましょう。

/team add red {"text":"赤チーム"}
/team join red @p

次に多いのが、JSONの書き間違いです。

/team modify red prefix {"text":"[赤] ","color":"red"}

このような形式で、{}、"text"、"color"、カンマの位置を確認してください。
慣れないうちは、まずコピペしてから文字だけ変えるのがおすすめです。

最小構成で動作確認する

何が原因か分からない場合は、下記だけで確認しましょう。

/team add test {"text":"テスト"}
/team modify test color green
/team join test @p
/team list test

これで自分が test チームに入っていることが確認できれば、/team 自体は正常に動いています。
あとは、セレクターや個別設定のミスを見直せばOKです。

13. まとめ

以上、Java版の /team コマンドの使い方を解説しました。

/team は、最初は少し難しく見えますが、使う順番はかなりシンプルです。

/team add red {"text":"赤チーム"}
/team modify red color red
/team modify red friendlyFire false
/team join red @p

まずは、この4行を覚えれば大丈夫です。

要点を整理すると、

/team はJava版限定のチーム管理コマンド
チームIDは英数字中心、表示名は日本語OK
color で名前色や発光輪郭色を変えられる
friendlyFire false で同士討ちを防げる
collisionRule never で押し合いを止められる
nametagVisibility で名前表示を細かく制御できる
@a[team=red] のように、チーム単位でコマンド対象を絞れる

このあたりを押さえておけば、PvP、配布マップ、サーバーロビー、イベント会場などでかなり応用できます。

コマンドは、いきなり全部を覚えようとすると大変です。
まずは赤チームと青チームを作って、名前の色を変えて、同士討ちをオフにするところから試してみてください。

慣れてきたら、team= セレクターを使って、チームごとのエフェクト付与やテレポート処理にも挑戦してみましょう。

では、本日はここまでで終わります。
最後までご覧いただき、ありがとうございました。
柚子クラでは他にも便利コマンドやマイクラ仕様解説をまとめているので、ぜひご覧くださいね(^^♪

14. 参考文献

この記事を書くにあたり、以下の公式情報・コミュニティWikiを参考にしています。

目次